Currently,
R and
S must both be polynomial rings over the same base field.
This function first checks to see whether M will be a finitely generated R-module via F. If not, an error message describing the codimension of M/(vars of S)M is given (this is equal to the dimension of R if and only if M is a finitely generated R-module.
Assuming that it is, the push forward
F_*(M) is computed. This is done by first finding a presentation for
M in terms of a set of elements that generates
M as an
S-module, and then applying the routine
coimage to a map whose target is
M and whose source is a free module over
R.
Example: The Auslander-Buchsbaum formula
Let's illustrate the Auslander-Buchsbaum formula. First construct some rings and make a module of projective dimension 2.
i1 : R4 = ZZ/32003[a..d];
|
i2 : R5 = ZZ/32003[a..e];
|
i3 : R6 = ZZ/32003[a..f];
|
i4 : M = coker genericMatrix(R6,a,2,3)
o4 = cokernel | a c e |
| b d f |
2
o4 : R6-module, quotient of R6
|
i5 : pdim M
o5 = 2
|
Create ring maps.
i6 : G = map(R6,R5,{a+b+c+d+e+f,b,c,d,e})
o6 = map(R6,R5,{a + b + c + d + e + f, b, c, d, e})
o6 : RingMap R6 <--- R5
|
i7 : F = map(R5,R4,random(R5^1, R5^{4:-1}))
o7 = map(R5,R4,{7616a + 9625b + 5245c + 379d - 15546e, - 302a - 1797b + 6011c - 638d - 5558e, - 10029a + 3831b + 1413c + 12789d + 9612e, 3134a - 4485b - 10370c - 1923d + 8841e})
o7 : RingMap R5 <--- R4
|
The module M, when thought of as an R5 or R4 module, has the same depth, but since depth M + pdim M = dim ring, the projective dimension will drop to 1, respectively 0, for these two rings.
i8 : P = pushForward(G,M)
o8 = cokernel | c -de |
| d bc-ad+bd+cd+d2+de |
2
o8 : R5-module, quotient of R5
|
i9 : pdim P
o9 = 1
|
i10 : Q = pushForward(F,P)
3
o10 = R4
o10 : R4-module, free, degrees {0, 1, 0}
|
i11 : pdim Q
o11 = 0
|
Example: generic projection of a homogeneous coordinate ring
We compute the pushforward N of the homogeneous coordinate ring M of the twisted cubic curve in P^3.
i12 : P3 = QQ[a..d];
|
i13 : M = comodule monomialCurveIdeal(P3,{1,2,3})
o13 = cokernel | c2-bd bc-ad b2-ac |
1
o13 : P3-module, quotient of P3
|
The result is a module with the same codimension, degree and genus as the twisted cubic, but the support is a cubic in the plane, necessarily having one node.
i14 : P2 = QQ[a,b,c];
|
i15 : F = map(P3,P2,random(P3^1, P3^{-1,-1,-1}))
3 3 5 6 1 1 3
o15 = map(P3,P2,{a + -b + -c + -d, -a + -b + 3c + -d, 2a + 2b + -c + 2d})
2 4 2 5 2 2 4
o15 : RingMap P3 <--- P2
|
i16 : N = pushForward(F,M)
o16 = cokernel {0} | 192803920ab+3872000b2-100752640ac-90384280bc+45371792c2 19280392a2-1599700b2-20199212ac+1263340bc+5097396c2 751742269585639000b3-1013376901206805800b2c-37898341505118416ac2+377100386363449400bc2-4871706861558368c3 0 |
{1} | 168556371a-278124715b-55820579c -24448483a-4257895b+11245383c 7959610312630135177a2-1748400408979854695ab+2274431664639651650b2-13360141749881148547ac+1432388403661014200bc+4328531362748309866c2 2740754a3-546990a2b+544775ab2+389125b3-5856405a2c+863540abc-582300b2c+3566540ac2-234990bc2-670265c3 |
2
o16 : P2-module, quotient of P2
|
i17 : hilbertPolynomial M
o17 = - 2*P + 3*P
0 1
o17 : ProjectiveHilbertPolynomial
|
i18 : hilbertPolynomial N
o18 = - 2*P + 3*P
0 1
o18 : ProjectiveHilbertPolynomial
|
i19 : ann N
3 2 2 3 2
o19 = ideal(2740754a - 546990a b + 544775a*b + 389125b - 5856405a c +
-----------------------------------------------------------------------
2 2 2 3
863540a*b*c - 582300b c + 3566540a*c - 234990b*c - 670265c )
o19 : Ideal of P2
|
Note: these examples are from the original Macaulay script by David Eisenbud.